PROCEDURE set_lov_buttons IS
   v_curr_item    VARCHAR2(30);
   v_curr_block   VARCHAR2(30);
   v_block_item   VARCHAR2(61);
BEGIN
   -- get the first block name in the form
   v_curr_block := get_form_property(
      get_application_property(current_form_name),
      FIRST_BLOCK);
   --
   -- loop through all blocks
   WHILE v_curr_block IS NOT NULL
   LOOP
      v_curr_item := get_block_property(v_curr_block, FIRST_ITEM);
      --
      -- loop through all items in the block
      WHILE v_curr_item IS NOT NULL
      LOOP
         v_block_item := v_curr_block||'.'||v_curr_item;
         --
         -- turn off the mouse navigable property if this is a button
         IF get_item_property(v_block_item, ITEM_TYPE) = 'BUTTON'
         THEN
            set_item_property(v_block_item,
               MOUSE_NAVIGATE, PROPERTY_FALSE);
         END IF;
         v_curr_item := get_item_property(v_block_item, NEXTITEM);
      END LOOP;
      v_curr_block := get_block_property(v_curr_block, NEXTBLOCK);
   END LOOP;
END;